No Selectable Options - Hide_Reuse

Game Development ChoiceScript Help
1

Hello! I have a few hide_reuse choices that make the player go through every option, a specific order isn’t necessary. I’ve gotten some feedback saying that after picking all the choices, they’re met with an error that says there’s no selectable options while others don’t encounter any issues whatsoever. Is there anything wrong with what I have? Is there a much more stable alternative to hide_reuse?

*label investigate_menu
*choice
    *hide_reuse #Broken window
        *set investigate_clues +1
        *goto examine_window
    *hide_reuse #Ripped notebook
        *set investigate_clues +1
        *goto examine_notebook
    *hide_reuse #Footprints scuffed on the tile
        *set investigate_clues +1
        *goto examine_footprint
    *hide_reuse #Shattered vase
        *set investigate_clues +1
        *goto examine_vase
    *if investigate_clues = 4
        #Reconvene with ${santiago}
            *goto end_investigation

Alternatively I also have this below where there’s 5 to choose from but you’re only able to choose 4 if this helps.

*label currentveillan_menu
*hide_reuse

*choice
    #"Can you tell me more about The Spirit?"
        *set newveillan +1
        *goto fourseventeen_cvone
    #"Can I talk to the Divine Balance?"
        *set newveillan +1
        *goto fourseventeen_cvtwo
    #"What was the Divine Balance like?"
        *set newveillan +1
        *goto fourseventeen_cvthree
    #"What exactly is energy manipulation?"
        *set newveillan +1
        *goto fourseventeen_cvfour
    #"Do the Lumins report to the Divine Balance?"
        *set newveillan +1
        *goto fourseventeen_cvfive
    *if (newveillan > 4)
        #"Wait," you pause.
            *goto fourseventeen_cvoneone

Thank you in advance!

2

There doesn’t seem to be anything wrong with the code, did those that encounter the problem explain how it happened? Were they using old saves?

1 Like
3

It seems to be a mix of both. Some have tried to use old saves while others start new saves but the error still persists regardless.

4

It could be they need to clear browser cache as that can also cause problems, because code seems fine and as long as investigate_clues is initated as 0 and its not modified anywhere outside of this there shouldn’t be a problem.

5

I have had some issues with that command before, and I get used to not use it and instead use *selectable_if or just *if with some variables, like this:

*temp c1 0
*temp c2 0
*temp c3 0
*temp c4 0

*label investigate_menu
*choice
    *selectable_if (c1 = 0) #Broken window
        *set c1 1
        *set investigate_clues +1
        *goto examine_window
    *selectable_if (c2 = 0) #Ripped notebook
        *set c2 1
        *set investigate_clues +1
        *goto examine_notebook
    *selectable_if (c3 = 0) #Footprints scuffed on the tile
        *set c3 1
        *set investigate_clues +1
        *goto examine_footprint
    *selectable_if (c4 = 0) #Shattered vase
        *set c4 1
        *set investigate_clues +1
        *goto examine_vase
    *if investigate_clues = 4
        #Reconvene with ${santiago}
            *goto end_investigation

It’s a little more work but it was the only way to solve the problems I had that I could find.

2 Likes
6

From the look of the code the issue sounds like investigation can go above 4 so the last option that takes them to the next part doesn’t appear.

A temporary fix is to add another option that isn’t *hide_reuse such as

#[Bug]Click here if you have no other options.
*goto next_scene

2 Likes
7

Wouldn’t using >= instead of = then fix the bug?

*if investigate_clues >= 4
4 Likes
8

This worked for me, thank you so much for your help!

1 Like