Help with coding exceptions in nonbinary text

[zozopuff]

Hello. I feel like I should lead with: I have negative amounts of experience with code and that this is also my very first forum post so I might be doing something wrong. Please let me know.

So, my issue is that I’m trying to make sure I include nonbinary genders in my game, but I’m having difficulty figuring out how to change some wording exceptions; i.e. she wants/they want, he says/they say.

I’ve poked around the forums and found the guide by Harris Powell-Smith (tysm this was so helpful figuring out how to do perm variables to begin with), but when it comes to how to fix up the text, the examples are very overwhelming or I can’t figure out how I’m supposed to implement them.

If someone could explain it to me like I’m 5, I’d really appreciate it.

Currently my startup code for gender looks like this:

*create gender "Unknown"
*create they ""
*create them ""
*create their ""
*create person ""
*create child ""

[MeltingPenguins]

multireplace is your friend here.

you need a plur variable like this:
*create plur false

so that in the text you can go
${they} @{plur look|looks} or ${they}@{plur 're|'s}

creating it as false will apply singular verbs in this scenario as default. there’s a good template/tutorial over here

[zozopuff]

Thank you so much for this!

That was the tutorial that I was looking at earlier but it overwhelmed me a lot and the wiki seems to be pretty hit or miss. I couldn’t figure out how the plural variable related to multireplace or if I had to have a variable for every different type of instance. But this makes sense now! I really appreciate your time!

[MeltingPenguins]

If I may add how I do it in my own games (which is overall similar/identical, but smaller?)

*label pronouns
(flavourtext)

*fake_choice
   #He/Him.
      *set they "he"
      *set them "him"
      *set their "his"
      *set theirs "his"
      *set self "himself"
      *goto story_cont
   #She/Her.
      *set they "she"
      *set them "her"
      *set their "her"
      *set theirs "hers"
      *set self "herself"
      *goto story_cont
   #They/Them.
      *set they "they"
      *set them "them"
      *set their "their"
      *set theirs "theirs"
      *set self "themself"
      *set plur true
      *goto story_cont
   #Something else...
      *label pronouns_input
      Instead of she/he/they I use...
      *input_text they
      Instead of her/him/them I use...
      *input_text them
      Instead of her/his/their I use...
      *input_text their
      Instead of hers/his/theirs I use...
      *input_text theirs
      Instead of herself/himself/themself I use...
      *input_text self
      *goto pronouns_check

*label pronouns_check
${they}, ${them}, ${their}, ${theirs} and ${self}, right?
*choice
   #Yes.
      And is it [i]is/was[/i], or [i]are/were[/i]?
      *choice
         #Is/Was.
            *goto story_cont
         #Are/Were.
            *set plur true
            *goto story_cont
   #No. Lemme fix that.
      *goto pronouns_input

[zozopuff]

Oh my gosh, thank you! Imputing your own pronouns feels too big for me at my current ability, but this is so helpful to see. When I get braver I would love to implement this!

[MeltingPenguins]

The code above will provide a field for inputs by the player.

You could copy the code into a new gamefile and try it out. just add a

*label story_cont
*ending

underneath

[zozopuff]

Thank you for suggesting this! After poking at it for a bit, it’s really not as scary as it seems. I think I’ll try to add it to what I already have! I appreciate it so much!

[MeltingPenguins]

Good luck