ChoiceScript Saving Plugin (Update: April 2023)

Aera_Viing · 2018-01-31T06:30:36.118Z

Hopefully this is still relevant? I’m trying to get this saving system to work for myself, yet a lot of the files and links to dropboxes no longer work. Has this been moved elsewhere or…?

Szaal · 2018-01-31T11:11:40.077Z

I believe the one you’re looking for is smPlugin.js (which is still active, btw)

Aera_Viing · 2018-01-31T21:39:10.416Z

Ah, so the one I had was correct. Ok so, here’s the next thing, I have the smPlugin.js in the folders, and I have the *sm_init line, and it still says that *sm_init isn’t a valid command

Szaal · 2018-02-01T02:35:16.103Z

Nah, the format you wrote is not complete.
It goes

*sm_init TheCodenameForYourSaveFile | NumberOfSaveSlots

mine is *sm_init hkbe | 5, for example.

Keep in mind that both randomtest and quicktest hate this code, so you might want to remove it before testing your game with them.

CJW · 2018-02-01T11:34:59.918Z

Have you made the necessary edits to index.html? (Scroll up)

Curious_Boy · 2018-02-01T15:00:53.993Z

hope this help you, this is what i did :

Fool's Fantasy [WiP] (CHAPTER ONE COMPLETED! UPDATED: 24/01/18) Works In Progress

check this thread : CJW save plugin and this for step by step : step-by-step and i know its quite confusing (i feel ya)…, basically you need to download the plugins (smPlugin.js and smPluginMenuAddon.js) → put it in the web folder of your choicescript game (outside mygame folder) [drop%20plugin%20in%20web%20folder] → and then open the index.html in the mygame folder with notepad (i used notepad++) [html%20file] → and then add these lines of code (look at the picture) <script src="../sm…

Aera_Viing · 2018-02-01T20:44:07.503Z

Ah! I don’t have the smPluginMenuAddon.js ! That would do it. Sadly the link given in that step-by-step is also…no longer functioning.

Aera_Viing · 2018-02-01T20:47:06.286Z

Alright nope I got everything, edited the index and added the code, I have the sm_init mepm | 5 line and it’s saying I have a script error

Aera_Viing · 2018-02-01T21:54:47.116Z

Alright nevermind, everything works now, apparently the game just decided to be all fine now. Thanks for your help ^.^

Curious_Boy · 2018-02-01T22:39:20.525Z

just to be sure you’ve got everything you need, you can find smPluginMenuAddon.js <<- in this post

fairlyfairfighter · 2018-02-16T21:24:20.578Z

Haha this is so old but I love you I forgot to put the .js on the end of “smPluginMenuAddon” goddamn you’re my hero.

vessynessy20 · 2018-02-27T02:12:29.000Z

EDIT: Oh my gosh never mind I fixed it! All I had to do was delete an incomplete *sm_init I had in my startup file a few lines below the completed version, and it booted up just fine! And I’ve tested the load/save features and it all works perfect! I guess I forgot to delete it from when I was messing with the placement order in relation to all the *creates and stuff!

Okay so I got the SMPlugin.js and SMPluginMenuAddon.js, and I put them in the proper folders and I used notepad++ to open SMPlugin and put my gameid into it, and I also put sm_init into my startup.txt, as well as wrote the proper script direct things into the INDEX file, so that’s all good. But what isn’t good is I’m getting an error now that says:

“SaveMod: Non existent game_id argument for *init_savemod!”

I don’t know what this even is or where to go to even fix it! Please help? Did I have to put *init_savemod into my startup file too, like under sm_init or what?

Szaal · 2018-02-27T07:55:43.264Z

vessynessy20:

nd I used notepad++ to open SMPlugin and put my gameid into it,

I don’t recall that you need to do anything with the plugin files itself

All you need to do is:

Grab the .js plugin files
Edit the index.html to include the plugin
Edit your startup.txt to include the *sm_init command

CJW · 2018-02-27T11:42:17.202Z

vessynessy20:

open SMPlugin and put my gameid into it

Undo that. *sm_init does it for you these days. You don’t need to touch any js files.

Szaal · 2018-02-27T13:20:03.198Z

Nah, you know? I think it’s about time to edit the first post to lead ppl to the latest plugin post. And probably try to simplify the installation steps.

Spectrum · 2018-04-09T22:42:57.305Z

I’m having…uh…well…

Looks%20Good%20To%20Me1920×1080 43.6 KB

…yeah. The save system isn’t popping any errors, and the game loads…something, but it’s corrupted. I’m not an expert, but I’m pretty sure there should only be one “Next” button.

I’ve been debugging this on my own for a couple hours now and I’m at my wit’s end. I’ve worked with a fresh download of ChoiceScript in the example game, modifying only startup.txt, smPlugin.js, and index.html.

In index.html, I added the following line (after scene.js and ui.js):

<script src="../smPlugin.js"></script>

in smPlugin.js, I game my game a unique game ID without touching anything else:

game_id: "save_tester",

And here’s my entire startup.txt (170 lines total, click to reveal):

startup.txt

*title Save System Tester 9000
*author Your Face
*scene_list
  startup
  animal
  variables
  gosub
  ending
  death

*create leadership 50
*create strength 50
*create current_save_slot 1
*create loading false

*sm_init save_tester | 3

*label start

This game is licensed under the ChoiceScript License (CSL) v1.0 as a noncommercial work. To view a copy of this license, 
*link http://www.choiceofgames.com/LICENSE-1.0.txt click here.

Choose an option, then press "Next" to confirm.

*label A
*choice

  *selectable_if (((savemod_slot_1 = "No Data") or (savemod_slot_2 = "No Data")) or (savemod_slot_3 = "No Data")) #New Game.
    *comment *set sound true
    Select an empty save slot.

    *choice

      *selectable_if (savemod_slot_1 = "No Data") #Slot 1: ${savemod_slot_1}
        *set current_save_slot 1
        *comment *goto_scene c0_introductions
        *goto test

      *selectable_if (savemod_slot_2 = "No Data") #Slot 2: ${savemod_slot_2}
        *set current_save_slot 2
        *comment *goto_scene c0_introductions
        *goto test

      *selectable_if (savemod_slot_3 = "No Data") #Slot 3: ${savemod_slot_3}
        *set current_save_slot 3
        *comment *goto_scene c0_introductions
        *goto test

      #Return to Main Menu.
        *goto start


  *selectable_if (((savemod_slot_1 != "No Data") or (savemod_slot_2 != "No Data")) or (savemod_slot_3 != "No Data")) #Continue.
    *comment *set sound true
    Select a save slot to load.

    *choice

      *selectable_if (savemod_slot_1 != "No Data") #Slot 1: ${savemod_slot_1}
        *set current_save_slot 1
        *set loading true
        *sm_load 1 | false
        *goto loading

      *selectable_if (savemod_slot_2 != "No Data") #Slot 2: ${savemod_slot_2}
        *set current_save_slot 2
        *set loading true
        *sm_load 2 | false
        *goto loading

      *selectable_if (savemod_slot_3 != "No Data") #Slot 3: ${savemod_slot_3}
        *set current_save_slot 3
        *set loading true
        *sm_load 3 | false
        *goto loading

      #Return to Main Menu.
        *goto start


  *selectable_if (((savemod_slot_1 != "No Data") or (savemod_slot_2 != "No Data")) or (savemod_slot_3 != "No Data")) #Delete A Save.
    Select a save slot to delete.

    *choice

      *selectable_if (savemod_slot_1 != "No Data") #Slot 1: ${savemod_slot_1}
        *sm_delete 1
        *goto start

      *selectable_if (savemod_slot_2 != "No Data") #Slot 2: ${savemod_slot_2}
        *sm_delete 2
        *goto start

      *selectable_if (savemod_slot_3 != "No Data") #Slot 3: ${savemod_slot_3}
        *sm_delete 3
        *goto start

      #Cancel and return to Main Menu.
        *goto start


*label test
Your majesty, your people are starving in the streets, and threaten revolution.
Our enemies to the west are weak, but they threaten soon to invade.  What will you do?

*choice
  #Make pre-emptive war on the western lands.
    If you can seize their territory, your kingdom will flourish.  But your army's
    morale is low and the kingdom's armory is empty.  How will you win the war?
    *choice
      #Drive the peasants like slaves; if we work hard enough, we'll win.
        Unfortunately, morale doesn't work like that.  Your army soon turns against you
        and the kingdom falls to the western barbarians.
        *goto test2
      #Appoint charismatic knights and give them land, peasants, and resources.
        Your majesty's people are eminently resourceful.  Your knights win the day,
        but take care: they may soon demand a convention of parliament.
        *goto test2
      #Steal food and weapons from the enemy in the dead of night.
        A cunning plan.  Soon your army is a match for the westerners; they choose
        not to invade for now, but how long can your majesty postpone the inevitable?
        *goto test2
  #Beat swords to plowshares and trade food to the westerners for protection.
    The westerners have you at the point of a sword.  They demand unfair terms
    from you.
    *choice
      #Accept the terms for now.
        Eventually, the barbarian westerners conquer you anyway, destroying their
        bread basket, and the entire region starves.
        *goto test2
      #Threaten to salt our fields if they don't offer better terms.
        They blink.  Your majesty gets a fair price for wheat.
        *goto test2
  #Abdicate the throne. I have clearly mismanaged this kingdom!
    The kingdom descends into chaos, but you manage to escape with your own hide.
    Perhaps in time you can return to restore order to this fair land.
    *goto test2


*label test2
*set loading false

*if current_save_slot = 1
  *sm_save 1 | false
  *goto test3
*elseif current_save_slot = 2
  *sm_save 2 | false
  *goto test3
*elseif current_save_slot = 3
  *sm_save 3 | false
  *goto test3
*else
  *bug Invalid variable at scene startup, label test2, statement 1, inputs: ${current_save_slot}


*label test3

*if loading
  Loading...

  *page_break
  
  Loaded!
  
  *finish
*else
  *finish

*label loading
*comment blank label so ChoiceScript doesn't complain, doesn't like #choices/*if statements that end in *sm_load

So far, I’ve tried:

Adding *if statements to check if the game is loading (pointless in hindsight, as loading overrides the checked variable)
Moving *sm_init around (no dice)
Adding save slots (the slots work, but the saves are still corrupted)
Adding a *goto to a blank *label immediately after *sm_load (errors stopped popping up, but saves were still corrupted)
Changing the point of save (corrupts no matter where I put it)
Adding a *page_break immediately after *sm_load (maybe my computer was just slow? No, it wasn’t)
Virgin sacrifices (volcano god didn’t know either)

I’m throwing in the towel. I need help. Anyone know what’s up?

CJW · 2018-04-09T22:46:40.991Z

smPlugin works by overriding some core CS functions so it’s always plausible that’s it’s just buggy.
I’ll take a quick look.

Szaal · 2018-04-09T23:28:29.001Z

Iirc, Dan updated the choicescript so it’ll properly reads ${} in *stat_chart bars.

CJW · 2018-04-09T23:58:54.927Z

Doubt that would have had much affect, but perhaps some recent change might have. I can see the problem you’re having @Spectrum, but I can’t see as to why just yet. It seems to work OK using the smPluginMenuAddon… Which is strange, as that just makes calls to smPlugin under the hood.

CJW · 2018-04-10T00:09:50.578Z

Right. It’s not your save routines. Took me a while to realise this as well. It’s your loads that are the problem, you’re triggering an implicit *finish by jumping to the end of the file, whilst simultaneously trying to load back to the middle of it.

Just add the ++ lines, as below (without the ++'s):

*label loading
*comment blank label so ChoiceScript doesn't complain, doesn't like #choices/*if statements that end in *sm_load
++ Loaded.
++ *page_break Continue

That gets you back to roughly where you need to be, might still need to tweak it a bit, depending on your exact use case.