The War for the West [Releasing Nov 14]

I just added at least new five endings where you can survive, with some big new branches. I still have to revise those last bits I’ve decided to add, but I think they are running OK.

24 Likes

Will try it right away

You need to mention @MahatmaDagon sometime he miss comment

2 Likes

@MahatmaDagon I don’t see the option but I’ll keep hoping for it. I also hope there will be the choice to confess love to Jenneth even when preempting the Triple Chalice. If the only way to convince Jenneth to marry the MC is to go through with the Triple Chalice’s trap, then some MCs might do just that. It looks like at the moment secondSummit.txt assumes Jenneth was confronted or otherwise knows that the Triple Chalice plan has failed but it is possible to head to the summit without confronting Jenneth or the MC’s council.

It feels like dealing with Dullis should also occur if the Triple Chalice manages to stage their trap at the Summit.

Here are some typos in the latest version.

Regardless, Danna was against it. She believed herlsef the rightful heir, and would fight to keep her seat.

It should be herself.

#“But why? Why the others here had to die? Why am I given the choice to remain alive?”

It should be did the others here have.

But what do they have in common? Why have your mind returned to the past after dying in those places?

It should be has.

*hide_reuse *if (workingWithThem) #“Since when have you working with the Triple Chalice?”

It should be have you been working or have you worked.

“It was one of the reasons as to why we would capture you by the time of the Lords Summit. Perhaps we would explain the situation and you would agree to do what was necessary, but if not you would be drugged forced you into intercourse. As many times as it became necessary, in order to produce a child.”

It should be drugged and forced.

 #I raised my army and conquered Dullis by force.
  *set alternateEnding 1
  *goto warWithDullis

 #I let the matter be, hoping that we would ally ourselves as independent nations in the future.
  *set alternateEnding 2
  *goto inTheFuture

 *selectable_if ((dullacsAffair) and (treasury >= 10000)) #I contacted the bastard son of Lord Dulsen and funded his rebellion in exchange of loyalty. (₳10000)
  *set alternateEnding 3
  *goto bastardFunding

 *if ((marriedWithDullis) and (treasury >= 10000)) #I hired as many assassins as it took to make sure ${heir} was the last claimant alive." (₳10000)
  *set alternateEnding 4
  *goto manyAssassins


*label inTheFuture
*goto_scene nothingReallyEnds


*label bastardFunding
*goto_scene nothingReallyEnds2



*label manyAssassins
*goto_scene nothingReallyEnds2


*if alternateEnding 0
 *goto allGood

*if alternateEnding = 1 
 *goto friendsLater

*if alternateEnding = 2 
 *goto wonWar

*if alternateEnding = 3 
 *goto bastardFunding

*if alternateEnding = 4 
 *goto manyAssassins

The variable names and “if” statements do not line up for alternateEnding 1 and 2. War with Dullis sets alternateEnding to 1 so the “if” statement pointing to “wonWar” should check for “if alternateEnding = 1”. The “if” statement pointing to “friendsLater” should check for “if alternateEnding = 2”.

#“You though you would be able to become King even after killing most of the people in the Lords Summit. I think I can manage to reach the same goal with only one body to my name.”

It should be thought.

3 Likes

@Carthe Oops! I forgot to remove that, it was something I had done to facilitate the automatic tests of the game. By removing Cardeed from the tests I noticed that they would go 100x faster. I’ll be fixing this right now, thanks for pointing it out.

@Norilinde I’m still not sure what to do about some of those elements. I’m trying to think of a way to connect the Jenneth RO possibility with that particular branch without it feeling forced or having less impact than it does on the alternate one, but I don’t feel I can just copy paste it.

As for the path of going there without confronting her/telling the council, I do need to correct those things. If you haven’t done those things and you haven’t sent letters to Boglan or Dullis, there is indeed no way for them to know you have knowledge of what is going to happen.

Regardless, I agree that dealing with Dullis should also occur if the TC manages to stage their trap. It will mostly be a matter of connecting those scenes together.

Thanks for the feedback! I’ll be at least fixing the typos you mentioned and updating the public version of the game with it.

EDIT:

You mean in secondSummit.txt(the one you quoted)? Those *ifs were there for reference, they are not actually “read” by the code" because all the other possibilities already lead to other scenes and the game never reaches them.

I think it is working fine, but I’ll take a closer look.

1 Like

Can your armor change if you get the abyssal armor?

You only get the armor after the duel, so there’s no way to do that. I think it is a cool idea, thought.

You are correct. I did mean secondSummit.txt. I apologize for not realizing that the part of the code I quoted never gets reached. I did not intend to waste your time on that.

Maybe the Sight has a better chance of triggering not just for the MC’s death but for the death of someone whose life means more to some MCs than their own. Jenneth might or might not agree but for some MCs letting the Summit end in a bloodbath as the only way to be with the one they loved could be thought of as romantic. My MC would still prefer to save Lady Avellyn and Lizra if possible.

2 Likes

It was updated 5 days ago on 29 April 2019.

@MahatmaDagon If it is not too much trouble, you might want to add the details to the changelog in the first post.

Thanks , i been very busy

1 Like

Umm, if anyone could tell me how to fight the giant knight and get blessed by the genderless…it would be appreciated.:smirk_cat::smirk_cat:

I found a bug regarding the path were you see into the future of the events leading up to the summit. After confronting Jenneth, if I bring her along with me either in secret or my companion I’m automatically brought into the convo with Lady Sessanah. It is also the same if I only choose to warn Lady Avenly or no one at all.

1 Like

So how do we get this New endings

2 Likes
There are multiple ways to defeat the giant knight. I included the relevant source code in the details here.

The relevant source code is from theSiege.txt.

*label bigGuy
*image giant.png
A huge knight - a beast of a man covered in platemail armor - swings a large mace, brutally pushing a couple soldiers out of his way. He clearly aims to reach you.

"FOR KING NOYEDAS!" he yells, from beneath his closed helm.
*goto forSielccia

*label forSielccia
*fake_choice
 *hide_reuse #Stand back and let your guards stop him.
  *goto letTheGuards

 *hide_Reuse #Retreat to a safe position.
  *goto retreatBattlements

 *hide_reuse #Face him yourself.
  *goto faceHimYourself


*comment /////////////////////////////////////////////////////////
*comment ////////                  FACE HIM                   ///
*comment ///////////////////////////////////////////////////////
*label faceHimYourself
"The little ${heraldry} has the courage to face me?" the knight asks, his voice amused. He walks slowly towards you, unaffected by the carnage that occurs behind him, as if accustomed to it.

*if ((social >= 40) or (lore >= 40))
 You notice a faint northern accent in his voice.
*goto faceHimYourself1x

*label faceHimYourself1x
*fake_choice
 *hide_reuse *if ((social >= 40) or (lore >= 40)) #"What is a northerner doing here?"
  "Murdering nobles who stand in my way!" He declares, as if finding it entertaining. Even muffled by the helmet, his voice is loud enough to be propelled over everything else.
  *goto faceHimYourself1x

 #"For the Two!"
  *goto meAndTheGiant

 #"For ${yourLands}!"
  *goto meAndTheGiant

 #"You die now, scum!"
  *goto meAndTheGiant

 #Say nothing.
  *goto meAndTheGiant


*label meAndTheGiant
*if combat <= 25
 There isn't enough space to maneuver properly on the battlements, and the first blow from his mace hits your ${weaponName} and takes it away from your hand. 
 *goto disarmed

*if combat > 25 
 There isn't enough space to maneuver properly on the battlements, but you manage to avoid his first blow by quickly stepping back, away from his reach.
 *goto meAndTheGiant2

*label meAndTheGiant2
You have a brief moment to consider your course of action.
*goto meAndTheGiant2x

*label meAndTheGiant2x
*fake_choice
 *hide_reuse #Try to keep avoiding his strikes and tire him out.
  *goto tireHimOut

 *hide_reuse #Try to slide forward and cut him behind the knees.
  *goto slideForward

 *hide_reuse #Try to lure him to the embrasure and make him fall from the edge of the walls.
  *goto lureHim


*label tireHimOut
*if combat >= 40
 You move swiftly between his attacks, changing position as he keeps missing you.

 "Stay put, you mulching moth!" He yells, panting underneath his closed helmet.
 *goto tireHimOut2

*if combat < 40
 You try to move swiftly between his attacks, but the man sees through your intentions. He faints an attack and, as you move yourself to avoid it, he crushes your arm with a sundering impact that makes you drop your blade.
 *goto disarmed

*label tireHimOut2
*comment implement more options here
Eventually the opportunity comes. A violent blow full of strength and frustration misses you and hits the ground, the head of the mace breaking some of the stone around the impact point. The large man has to bend his knee to retain his weapon, leaving himself exposed for a brief moment.

*fake_choice
 #Rush towards him and carve your sword inside his helmet visor.
  *goto giantRusher

 #Step on his arm for support and carve your sword in his nape, between his helmet and his gorget.
  *goto giantClimber

*label giantRusher
You rush towards him, holding ${weaponName} with both hands like a spear. The man is slow to react, but still manages to grab you and hold you against him with both arms, in an a deadly embrace. Still, while crushed by his strength, you are able to carve your sword inside the opening on his visor. He yells in gruesome pain and is forced to let you go. You get out of his reach and assess the situation.

There is blood pouring from his helmet, and he takes it away. His bony face - which certainly would never have been described as pretty before - is now a mess of bloody and exposed meat, both his eyes indiscernible behind all the gore. He moans in pain and rage, blindly waving his arms, trying to grab you.

*page_break

*fake_choice
 *selectable_if (combat >= 50) #Grab his mace and swing it against his unprotected head.
  *set giantFall true
  It's weight is almost too much to bear, but you remember your lessons and spread your legs, letting your body adjust to it. You slowly and silently move towards the man with great effort, avoiding his random grabs, and when you have enough reach you swing the large mace upwards, all your muscles aching with the motion. The weapon hits the knight violently on the chin, breaking his jaw and sending it towards his palate. He falls and you take the time to smash the rest of his head as well, to be sure that he dies.
  *goto hesDead
 
 #Slash your sword against his unprotected head.
  *if (combat >= 45)
   *set giantFall true
   While avoiding his wavering arms that try to grab anything around him, you approach and deliver a single strike that has enough strength behind it to end this business forever.
   *goto hesDead

  *if (combat < 45)
   You approach him in order to strike, but his wavering arms find you before you have time to react, and close around your body. He does not give you space to do much, and while holding you with his deadly embrace, runs blindly through the battlements until he finally stumbles upon the edges. The last thing you hear is the deep laugh of a madman as you both go down towards certain death.
   *goto_scene youDied

 #Lure him to the edge of the walls.
  *goto lureboys


*label lureBoys
You consider what are the right words to say to lure him, if there are any.

*fake_choice
 #"Come and get me!" 
  *goto lureHimBlind
  
 #"Ready to yield?"
  *goto lureHimBlind

 #"Let's finish this at once." 
  *goto lureHimBlind

 #"You fight as well as your mother sards, good sir."
  *goto lureHimBlind

 #"At least you will never have to see yourself in the mirror again."
  *goto lureHimBlind





*label lureHimBlind
*set giantFall true
He blindly charges towards your voice and you sidestep at the last moment, letting him fall through the embrasure towards his death.

*if (largeStones) 
 The sound he makes when he reaches the ground is similar to the one produced by the boulders that were thrown before.

*goto hesDead

*label giantClimber
It is all done before he can react. You jump over him using his arm for support and turn the ${weaponName} like a giant poniard, holding it above from the grip and thrusting the tip on the back of his head. He struggles for a bit and loses balance, falling towards the ground. For a moment you think he's going to crush you with his weight, but you are able to roll away.
*goto hesDead

*label hesDead
*page_break
*achieve giantslayer
*if (giantFall = false)
 He's dead. You grab your sword back from his body, half of the blade covered with blood.

You take a moment to catch your breath, assessing what is happening on your side of the walls; The nearby assailants are being repelled, and you then join your men in finishing the last of them.
*page_break
*goto theOtherSide

*label lureHim
You keep on avoiding his strikes while positioning yourself close to the edge.

*if (combat >= 45)
 *set giantFall true
 By the time he realizes what you were doing, it is too late; you sidestep and he loses his balance, stumbling upon the embrasures and the melons. The man tries to recover himself, but you are there to give him one final push towards his death. 
 *goto hesDead

*if (combat < 45)
 As he is about to fall for your trap, he decides to suddenly stop. 

 "No. You won't trick me." 

 The way you two are disposed on the battlements right now, you have nowhere else to run; the knight with the mace in front of you, the edge of the battlements and the free fall at your back. Either way, you'll end up smashed.
 *goto whatNowGiant

*label whatNowGiant
*page_break Sard.
*if (social >= 40)
 *set giantFall true
 Your quick mind decides on one last desperate attempt at luring him towards the edge. You start using all kinds of slurs you've heard both in your household and from the mouths of soldiers when they thought you weren't listening. You speak insults from the highest of courts and the lowest of slums. You even invent some bad words of your own in order to detail the sexual services the knight's mother provided to both armies. He gets so angry that he seems to forget all else, and throws his entire strength behind a single blow of his mace intended to end your life immediately.

 That's it. You manage to avoid it at the last moment and he falls to his death, propelled by his own force.
 *goto hesDead

*if (social < 40)
 He simply throws his mace forward, and the impact of it pushes you from the edge. You fall, horrified, the ground approaching rapidly, and then-
 *goto_scene youDied


*label slideForward
*if combat >= 50
 *goto forwardSlider

*if ((combat >= 20) and (combat < 50)) 
 You slide forward barely in time to avoid a blow from his mace. As you turn and try to slash the unprotected spot behind his knees, he immediately kicks you in the face. You roll away, blood running from your nose, and when you get a hold of yourself again, you're no better than before.
 *goto meAndTheGiant2x

*if (combat < 20)
 As you are about to slide forward, the enemy predicts your intentions and kicks you in the chest. Then, with a quick swing of his mace, he disarms you.
 *goto disarmed

*label forwardSlider
*set giantFall true
You slide forward as the misses a swing of his mace. You turn and quickly slash the unprotected spot behind his knees, forcing him to bend them, yelling in pain. Then you use the ${weaponName} on the back of his head, between the gorget and the helmet, that sweet spot of death. 
*goto hesDead

*label disarmed
The next blow takes away your life.
*goto_scene youDied


*label letTheGuards
Three of your guards step in front of him, while all around swords clash and men yell of fury and pain. The knight's mace swings and crushes the shield of one of the soldiers, who loses his balance and is then thrown from the battlements. The other two men of your household try to take the opportunity to attack with their spears, but the enemy uses a hand to grab one of the weapons and bring its owner towards him.

He then smashes the man's head with his mace, breaking it in an unnatural way and casting the body towards the mess behind him.

*if (morale >= 5)
 *goto standHisGround

*if (morale < 5)
 *goto coward

*label coward
The last guard is overtaken by fear and drops his spear, pleading for mercy, but there is none to be had. The mace comes down against his skull, breaking its contents immediately. The giant laughs and then makes his way towards you.

*page_break
What will you do?
*goto forSielccia

*label standHisGround
To his merit, the guard between the two of you still stands his ground. He is convict on not letting the enemy pass, and willing to die to protect his ${title}. You do not know his name, but you will remember him for the rest of your life; the way he stood there, spear and shield, the ${color} cape hanging around his shoulder, a small prayer whispering from his lips.

The large knight laughs as he smashes the guard's left arm. He keeps laughing as he swings the mace again and crashes it against his chest. He is still laughing as he steps on the man's face on his way towards you.

*page_break
*goto forSielccia

*label retreatBattlements
You step back, overwhelmed by the enemy's fury. He calls you a coward as his weapon crushes the chest a nearby soldier, and continues to run towards you, all steel and fury. His mace is about to fall down on you.

*page_break
*if ((metTull) and (tullisAlive)) 
 *goto redTullBattlements

*if ((metTull) and (tullisAlive = false)) 
 *goto soldiersSave

*if metTull = false
 *goto soldiersSave

*label soldiersSave
You feel something abruptly pulling you backwards, and then your field of vision is covered entirely by ${color}. It takes you a moment to realize that five of your knights stand there, between you and the enemy, and that the ${color} was from their capes, who also display the ${heraldry} of your House.

They stand in close formation, covering the entire width of that portion of the battlement, large shields pressed against one another, spears steady and pointed forward.

"Go, my ${title}. We will take it from here."

*goto imSafe

*label redTullBattlements
The sound of metal clinging against metal is loud as a thunder for a moment. You see a large red-haired man in simple leather armor putting himself between you and the enemy.

"Go, $!{title} ${name}!" Red Tull says, raising his sword against the knight's mace, already blood covering his garments, and you can't tell if its his or the enemy's. 

The two giants engage in a private duel amidst the chaotic battle on the walls, no one daring to come close to interfere, for there is little space between them.

Meanwhile, you retreat towards safety.
*goto imSafe

@ThatsOk It looks like 40 combat, or a combined 26 combat and 40 social could beat the giant if you wish to face him personally.

As for the genderless, you need to acquire the fallen star, make it into a sword, hunt something wicked successfully, bring back the corpse, give the corpse to the Inquisitor, then you get to go meet the genderless. Your best result at that point though may be them deciding you are not the hero for whom they search in which case you eventually leave with their thanks.

2 Likes

How do we get the holy ruler achievement?

why have we been given a set number of troops which we can upgrade? why not allow us to choose the amount that we want? i find it quite tiresome to have to train omly 200 troops at a time especially if i can train more.
you can also increase the amount of time needed to train the troops by the number of men sent into training.

after we purchased everything we can from the quartermaster, there isn’t anything else he can do. why don’t you put in the option to improve roads, market place, build more housing for peasants, expand the city maybe.

1 Like

There’s an option to improve roads if you attend to the ball and talk to Rochmaurg nicely.

1 Like

Found some errors on the path where see the coup coming

SPOILERS!!!

a letter to Lady Sessanah of House Drown, telling her about the dangerous events that will occur in her capital

This was when I sent a letter to Avellyn


I was able to select Jenneth as my companion for the summit even though I had just beheaded her (small execution)


I am getting tired of these senseless accusations. I came here to pay my respects and ask for you support, but if you want to decide this on the battlefield, Lady Larieth, I am happy to oblige."

Option uses my name instead of Dana’s when defending myself to her after mentioning that she’d break her brother’s heart by picking a fight.

5 Likes