# allow\_reuse limited attempts?

**URL:** <https://forum.choiceofgames.com/t/allow-reuse-limited-attempts/178171>\
**Category:** ChoiceScript Help\
**Created:** [June 27, 2026, 7:49pm UTC](https://forum.choiceofgames.com/t/allow-reuse-limited-attempts/178171 "2026-06-27T19:49:31Z")\
**Posts on this page:** 3\
**Page:** 1

<div class="post-metadata">

**Author:** ![setsunakutemo](https://avatars.discourse-cdn.com/v4/letter/s/e56c9b/32.png) [@setsunakutemo](https://forum.choiceofgames.com/u/setsunakutemo)\
**Post date:** [June 27, 2026, 7:49pm UTC](https://forum.choiceofgames.com/t/allow-reuse-limited-attempts/178171/1 "2026-06-27T19:49:31Z")

</div>

Is there a way that allows only a specific number of reusable choices? I was reading the KB but didn’t find anything other than just how to implement disable & reuse.

What I’m thinking:

```choicescript
*label friendTexts
*hide_reuse
*choice
    #friend1
        Blah blah blah
        *goto readText
    #friend2
        Blah blah blah
        *goto readText
    #friend3
        Blah blah blah
        *goto readText
    #friend4
        Blah blah blah
        *goto readText

*label readText
Do you want to read the other texts?
*choice
    #No
        *finish
    *allow_reuse_3 #Yes
        *goto friendTexts

```

**(I know _allow\_reuse\_3_ doesn’t exist, but I didn’t know how else to show what I mean)**

Otherwise, players are allowed to go back to friendTexts and eventually get the No Selectable Options error. Is there some easy way I’m overlooking, or do I just need to keep my additional loop that forces it to end?

Not critical, just thought it would be interesting if it’s possible.

---

<div class="post-metadata">

**Author:** ![MeltingPenguins](https://sea3.discourse-cdn.com/choiceofgames/user_avatar/forum.choiceofgames.com/meltingpenguins/32/255855_2.png) [@MeltingPenguins](https://forum.choiceofgames.com/u/MeltingPenguins)\
**Post date:** [June 27, 2026, 8:47pm UTC](https://forum.choiceofgames.com/t/allow-reuse-limited-attempts/178171/2 "2026-06-27T20:47:21Z")

</div>

One way I can think of is a \*temp variable for a counter so a new option pops up after a bit:

```choicescript
*temp friendtxt 0

*label friendTexts
*hide_reuse
*choice
    #friend1
        Blah blah blah
        *set friendtxt +1
        *goto readText
    #friend2
        Blah blah blah
        *set friendtxt +1
        *goto readText
    #friend3
        Blah blah blah
        *set friendtxt +1
        *goto readText
    #friend4
        Blah blah blah
        *set friendtxt +1
        *goto readText
    *if (friendtxt =4) #There are no further texts to read.
        *finish

```

Edit: alternatively you can have an \*if at readText

```choicescript
*label readText
*if (friendtxt <4)
 Do you want to read the other texts?
 *choice
    #No
        *finish
    #Yes
        *goto friendTexts
*else
 That'd be all
 *finish

```

---

<div class="post-metadata">

**Author:** ![will](https://sea3.discourse-cdn.com/choiceofgames/user_avatar/forum.choiceofgames.com/will/32/132033_2.png) [@will](https://forum.choiceofgames.com/u/will)\
**Post date:** [June 27, 2026, 9:46pm UTC](https://forum.choiceofgames.com/t/allow-reuse-limited-attempts/178171/3 "2026-06-27T21:46:26Z")

</div>

```choicescript
*hide_reuse
*temp books_read 0
*label select_book

*if (books_read >= 4)
  *goto no_more_books

*fake_choice
  # Book 1
    *gosub book_1
  # Book 2
    *gosub book_2
  # Book 3
    *gosub book_3
  # Book 4
    *gosub book_4
  *if (books_read >= 1)
    # Done reading.
      *goto no_more_books

*set books_read +1
*goto select_book

*label no_more_books

```